Repeated Roots of a 3rd Order Linear DE

Let's consider the linear differential equation given by

deq[y_] :=D[y,{t,3}] - 3 D[y,{t,2}] +3 D[y,{t,1}]-y==0

We can solve this in Mathematica:

DSolve[deq[y[t]],y[t],t]

What have we learned? Nothing! Let's instead use Mathematica to help us with the algebra that results from a solution which helps us learn.

Assume the solution looks like:

ϕ[t_] = Exp[r t]

Substitute into the differential equation:

deq[ϕ[t]]

Simplify the resulting equation to get the characteristic equation:

Simplify[%]

Mathematica doesn't know that it can cancel the term (e^(r t)), but we know that we can divide by that term since it does not equal zero. We get the characteristic equation:

characteristic = (((-1+r))^3)==0

Which we can solve:

Solve[characteristic,r]

Unsurprisingly, we find the root of the characteristic equation is 1 with a multiplicity of 3. We have found one solution,

(Subscript[y, 1])[t_] = Exp[t]

What do we do know? Before, we tried reduction of order, so let's do the same thing here.

Substitute into the differential equation the function u(t)(Subscript[y, 1])(t):

deq[u[t](Subscript[y, 1])[t]] /. r->1

Mathematica can simplify it for us a bit:

Simplify[%]

Since (e^t)does not equal zero, we can cancel, and we are left with the following differential equation which u[t] must solve:

deq2 = Derivative[3][u][t]==0

We can use Mathematica to solve this, but it is easy enough to see how this can be integrated (it is separable) to yield

u[t_]=(Subscript[C, 1])+t (Subscript[C, 2])+(t^2) (Subscript[C, 3])

And so the solution to the original differential equation is

sol[t_] = u[t] (Subscript[y, 1])[t]

From this, we can pick out the three linearly independent solutions:

(Subscript[y, 1])[t]
(Subscript[y, 2])[t_] = t (Subscript[y, 1])[t]
(Subscript[y, 3])[t_] = t^2 (Subscript[y, 1])[t]

We can verify this is a solution by back substituting into the differential equation:

Simplify[deq[sol[t]]]

We can check that the solutions are linearly independent by calculating the Wronskian:

Det[{{(Subscript[y, 1])[t],(Subscript[y, 2])[t],(Subscript[y, 3])[t]},{(Subscript[y, 1])'[t],(Subscript[y, 2])'[t],(Subscript[y, 3])'[t]},{(Subscript[y, 1])''[t],(Subscript[y, 2])''[t],(Subscript[y, 3])''[t]}}]

which will not equal zero, so these functions form a fundamental set of solutions.

And with this analysis, we have learned something.

Multiple Repeated Roots of a 4th Order Linear DE

Clear[u,ϕ,y,deq2,deq,v,w,sol,"(Subscript[y, 1])","(Subscript[y, 2])","(Subscript[y, 3])"]

OK, so reduction of order worked fine if the root was the only one that was repeated. What if you have multiple repeated roots? What happens then? We should work through this once to make sure the method presented in the book works. We would definitely not want to have to do this each time we solved a problem!

Let's look at the following example.

deq[y_] :=D[y,{t,4}] -2D[y,{t,2}]+ y==0

DSolve[deq[y[t]],y[t],t]

How can we see where this solution comes from? We can work through it, beginning with what we know about how to solve constant coefficient linear differential equations.

Assume the solution looks like (e^(r t)), substitute into the differential equation and simplify:

ϕ[t_] = Exp[r t];
deq[ϕ[t]]
Simplify[%]

Mathematica doesn't know that it can cancel the term (e^(r t)), but we know that we can divide by that term since it does not equal zero. We get the characteristic equation:

characteristic =  (((-1+(r^2)))^2)==0

Which we can solve:

Solve[characteristic,r]

We find the roots of the characteristic equation are +1 and -1with multiplicity of 2.  Two solutions are therefore

(Subscript[y, 1])[t_] = Exp[t];
(Subscript[y, 2])[t_] = Exp[-t];

Reduction of order is the next step. Let's work with u(t)(Subscript[y, 1])(t).

Simplify[deq[u[t](Subscript[y, 1])[t]]]

Since (e^t)does not equal zero, we can cancel, and we are left with the following differential equation which u[t] must solve:

4 u''[t]+4 Derivative[3][u][t]+Derivative[4][u][t]==0;

This is another constant coefficient linear differential equation. We can assume that
v[t] = u''[t], and v[t] is a solution of the differential equation:

deq2[v_] := 4 v+4 D[v,{t,1}]+D[v,{t,2}]==0

Assume the solution looks like  (e^((Subscript[r, 2]) t)), substitute into the differential equation and simplify:

(Subscript[ϕ, 2])[t_] = Exp[(Subscript[r, 2]) t];
deq2[(Subscript[ϕ, 2])[t]]
Simplify[%]

Once we cancel the exponential, we will have another characteristic equation, which will have root (Subscript[r, 2])=-2 of multiplicity 2. This means that the form of v is:

v[t_] = Exp[-2 t];

Now, v was a root of multiplicity 2 for deq2, so we can use reduction of order on it:

Simplify[deq2[w[t]v[t]]]

This differential equation can be solved for w''[t] by integrating (it is separable) and we find

w[t_] = (Subscript[c, 1]) t + (Subscript[c, 2]) ;

Remember that we said above that v(t)=u''(t)? And v(t) solved the differential equation deq2? That means that we can also say that u''(t)=v(t) w(t), since v(t) w(t) also satisfies the differential equation. We can integrate this to solve for u(t):

u[t_] = Integrate[Integrate[w[t] v[t],t] + (Subscript[c, 3]),t]+(Subscript[c, 4])

From this we can see that we have

Expand[u[t](Subscript[y, 1])[t]]

Finally, we have determined four solutions to the original differential equation. They can be read from the above as

Clear["(Subscript[c, 1])","(Subscript[c, 2])","(Subscript[c, 3])","(Subscript[c, 4])"]
(Subscript[y, 1])[t]
(Subscript[y, 2])[t]
(Subscript[y, 3])[t_] = t (Subscript[y, 1])[t]
(Subscript[y, 4])[t_] = t (Subscript[y, 2])[t]
sol[t_] = (Subscript[c, 1]) (Subscript[y, 1])[t] + (Subscript[c, 2]) (Subscript[y, 2])[t] + (Subscript[c, 3]) (Subscript[y, 3])[t] + (Subscript[c, 4]) (Subscript[y, 4])[t]
Simplify[deq[sol[t]]]