Vector Functions

Derivatives of Vector Functions

r[t_]={Cos[t],Sin[t],t}

curve= ParametricPlot3D[r[t],{t,-5,5},PlotStyle->{Blue,Thickness[0.02]}]

point[t_]:=Show[Graphics3D[{Green,Sphere[r[t],0.2]}],PlotRange->{{-1.5,1.5},{-1.5,1.5},{-5,5}}];

Manipulate[Show[point[t],curve],{t,-5,5}]

Velocity

v[t_]=r'[t]

velocity[t_]:=Show[Graphics3D[{Red,Thick,Line[{r[t],r[t]+v[t]}]}],PlotRange->{{-1.5,1.5},{-1.5,1.5},{-5,5}}];

Manipulate[Show[point[t],curve,velocity[t]],{t,-5,5}]

Notice that the velocity has constant length, but changes direction! This means the speed is constant, but the velocity is not.

Acceleration

The acceleration is not a zero vector:

a[t_]=v'[t]

acceleration[t_]:=Show[Graphics3D[{Green,Thick,Line[{r[t],r[t]+a[t]}]}],PlotRange->{{-1.5,1.5},{-1.5,1.5},{-5,5}}];

Manipulate[Show[point[t],curve,velocity[t],acceleration[t]],{t,-5,5}]

Example From Class

If the position is given by r(t)=<cos t,3(e^(2t)),3 (e^(-2t))>, find the velocity at (1,3,3).

Solutions

Define the position vector:

r[t_]={Cos[t],3 Exp[2t],3Exp[-2t]}

curve= ParametricPlot3D[r[t],{t,-1,1},PlotStyle->{Blue,Thickness[0.02]}]

Calculate the velocity vector:

v[t_]=r'[t]

The tangent line at any point along the curve is given by the vector equation:

rtangent[s_,t_]=r[t]+r'[t]*s

This sets up an animation easily:

tangent[t_]:= ParametricPlot3D[rtangent[s,t],{s,-2,2},PlotStyle->{Red,Thickness[0.02]}]
Show[curve,tangent[0]]

Manipulate[Show[curve,tangent[t]],{t,-1,1},PlotRange->{{0,25},{0,25},{-1,1}}]

The intersection of a cone and a plane

Here is the plane:

plane =Plot3D[1+y,{x,-5,5},{y,-5,5},ColorFunction->"RustTones"]

Here is the cone:

cone =Plot3D[(Sqrt[(x^2)+(y^2)]),{x,-5,5},{y,-5,5},ColorFunction->"CherryTones"]

Here is the intersection:

r[t_]={t,(((t^2)-1)/2),(((t^2)+1)/2)}

intersection = ParametricPlot3D[r[t],{t,-5,5},PlotStyle->{Blue,Thickness[0.02]}]

Show[plane,cone,intersection]

The intersection of a cylinder and a plane

Here is the plane:

plane =Plot3D[2-y,{x,-2,2},{y,-2,2},ColorFunction->"RustTones"]

Here is the cylinder:

cylinder =ContourPlot3D[(x^2)+(y^2)==1,{x,-1,1},{y,-1,1},{z,-5,5}]

Here is the intersection:

r[t_]={Cos[t],Sin[t],2-Sin[t]}

intersection = ParametricPlot3D[r[t],{t,-5,5},PlotStyle->{Blue,Thickness[0.02]}]

Show[plane,cylinder,intersection]

Integration of Vector Functions: Example 13.1.31 from text

A glider has acceleration a(t)=<-1,-1,-1> and initially the gider departed from  (10,10,10) with velocity v(t)=<0,0,0>. Find the position vector of the glider.

Solution

a[t_]={-1,-1,-1}

We integrate to get the velocity:

v[t_]=Integrate[a[t],t]

Notice that Mathematica did not include a constant of integration! We need one, since we have to use the condition that v(t) = < 0, 0, 0 > to determine it's value. We must put it in ourselves, and it needs to be a vector.

Solve[{0,0,0}==v[0]+{c1,c2,c3},{c1,c2,c3}]

In this case the constant was a zero vector, but that doesn't happen in general! So the velocity is given by:

v[t_]={-t,-t,-t}

Now we integrate again to get the position vector:

r[t_]=Integrate[v[t],t]

Again, we must put in the constant of integration ourselves, and use r(t) = < 3,0, 0 > to determine it's value. We must put it in ourselves, and it needs to be a vector.

Solve[{10,10,10}==r[0]+{c1,c2,c3},{c1,c2,c3}]

So the position is actually given by:

r[t_]={-((t^2)/2),-((t^2)/2),-((t^2)/2)}+{10,10,10}

Plots

curve= ParametricPlot3D[r[t],{t,-20,20},PlotStyle->{Blue}];

point[t_]:=Show[Graphics3D[{Green,Sphere[r[t],5]}],PlotRange->{{-190,15},{-190,15},{-190,15}}];

velocity[t_]:=Show[Graphics3D[{Red,Thickness[0.02],Line[{r[t],r[t]+v[t]}]}],PlotRange->{{-190,15},{-190,15},{-190,15}}];

It's a bit hard to see everything in one plot, so first here is a plot with the velocity vector (red line):

Manipulate[Show[point[t],curve,velocity[t]],{t,-18,18}]

In this case, the acceleration always points in the direction <-1,-1,-1>.