Problem 1.4.1 Automobile Manufacture

An automobile manufacturer makes a profit of $1,500 on the sale of a certain model. It is estimated that for every $100 of rebate, sales increase by 15%.

a) What amount of rebate will maximize profit?

b) Compute the sensitivity of your answer to the 15% assumption. Consider both the amount of rebate and the resulting profit.

c) Suppose that rebates actually generate only a 10% increase in sales per $100. What is the effect? What if the response is somewhere between 10 and 15% per $100 rebate?

d) Under what circumstances would a rebate offer cause a reduction in profit?

Ask the question

The variables of this problem are, with the units in brackets:

pm, Profit on the sale of a model of car [$/car]. pm = $1500/car.
r, Rebate [$/car].
rsf, Rebate scale factor [$/car]. rsf = $100/car.
rin, Sales increase based on rebate [%, no unit]. rin = 0.15.
n, Total number of cars sold when there is no rebate [car].
p, Total Profit [$].

We are assuming:
1)  For every $100 in rebate, sales increase by 15%.
2) r ≥ 0, or we will be increasing the price of the car.

We want to find the dollar amount of rebate that will maximize the profits.

Select the modeling approach

We will model this problem as a one dimensional optimization. Once we have the total profit as a function of rebate, we will find the maximum profit by taking the derivative of the function with respect to rebate, setting the derivative equal to zero, and solving the resulting equation for the rebate. This gives us the rebate which will maximize the profit to the dealer. We can check that this is a maximum by using the second derivative test, or simply noting that our function is a parabola opening down, so it must have a maximum and not a minimum.

Formulate the model

We wish to maximize the profit. The profit is given as:

pm  =  1500;
rin  =  15/100;
rsf  =  100;
p[r_, n_]  =  n*(1 + rin*r/rsf) (pm - r)

Unit Check: [car] * ( [ no unit] + [no unit]) ( [no unit] + [no unit] [$/car]/[$/car]) ([$/car] -  [$/car] ) = [$] 
Units are correct!

This is a multivariable model. We need to create a one variable model. We wish to find the rebate r that maximizes the profit, so we need to eliminate the number of cars sold from our model equation. The way we have written our equation, n is the number of cars sold when the dealer makes a profit of $1500/car. We do not need to know this number to determine what rebate to offer. We shall set n=1 in what follows.

To get an idea if our model is correct, let's plot the profit as a function of rebate:

Plot[{p[r, 1], 1500}, {r, -100.00, 1000.0}, Frame -> True, 
      PlotRange -> {1400, 1800}, 
      FrameLabel -> {"Rebate", "Profit", "", ""}]

This looks reasonable, so let's continue. It looks like there is a maximum profit when the rebate is about $400/car, and that at some point the rebate will act to reduce profits (around a rebate of $850).

Solve the model

Now, we wish to find the rebate that maximizes the profit. We do that by finding the derivative of the profit, setting it equal to zero, and solving for the rebate. We can see that what we have found is a global maximum since the profit function we have is parabolic opening down.

sol  =  Solve[D[p[r, 1], r] == 0, r]
or  =  r  /.  Last[sol]

N[or]

Since the rebate is $100 times the scaled rebate sr, we see that a rebate of $25/6*100=$416.67 will maximize the profit.

Answer the question

The dealer would maximize their profit if they offered a rebate of $416.67/car .

Sensitivity of result to the 15% amount

Here we will look at the sensitivity of our result to the estimate that you get a 15% increase in sales. This variable is called rin. We keep rin as a variable, and solve the model as before.

pm  =  1500;
Clear[rin];
rsf  =  100;
p[r_, n_]  =  
      n*(1 + rin* r/rsf) (pm - r)
sol  =  Solve[D[p[r, 1], r] == 0, r]

We now have the optimal scaled rebate as a function of the percentage of new sales that it attracts.

or  =  r /. First[sol]

Plot[or, {rin, 0, 1}, Frame -> True, 
      FrameLabel -> {"(Percentage of new sales)/100", "Optimal \
Rebate", "", ""}, PlotRange -> {-10, 1000}]

Notice from our graph that the optimal scaled rebate becomes negative for some percentage of new sales, rin. This does not make sense, since it means that we would be increasing the price of the car (negative rebate), and still getting a percentage increase in buyers! Since we know this will not happen, we can restrict rin to have a domain that keeps the optimal scaled rebate positive.

Solve[or == 0, rin]

N[%]

So the  increase in sales (rin) must be greater than 1/15 *100 % = 6.67%.

Sensitivityor[rin_]  =  Simplify[D[or, rin] rin/or]

Sensitivityor[0.15]

Sensitivity numbers can be thought of in the following manner. 

Sensitivity of x to r = (((((d(x))/x)))/((((d (r))/r)))), which is the ratio of the percent changes in the quantities.

 So, since the sensitivity of osr to rin is 0.8, we can say to some approximation that if rin, the sales increase based on rebate, goes up by 5% then the optimal rebate will go up by 4%. The sensitivity increases dramatically (and undergoes a sign change!) as rin approaches 1/15=0.06. Since this is not very far away from our estimate that we are given for rin of 0.15, we should be somewhat concerned about acting on the results of our model.

Plot[Sensitivityor[rin], {rin, 1/15, 0.4}, Frame -> True, 
      Axes -> False, 
      FrameLabel -> {"(Percentage of new Sales)/100", "Sensitivity \
(or, rin)", "", ""}]

We can also look at the profit as a function of the sales increase based on rebate. The sensitivity analysis for this situation is:

Sensitivityp[rin_]  =  
      Simplify[D[p[or, 1], rin] rin/p[or, 1]]

Plot[Sensitivityp[rin], {rin, 1/15, 0.4}, Frame -> True, 
      FrameLabel -> {"(Percentage of new Sales)/100", "Sensitivity \
(profit, rin)", "", ""}, Axes -> False]

Rebates generate a 10% increase in sales

pm  =  1500;
rin  =  10/100;
rsf  =  100;
p[r_, n_]  =  
      n*(1 + rin* r/rsf) (pm - r)
Plot[{p[r, 1], 1500}, {r, -100.00, 1000.0}, Frame -> True, 
      PlotRange -> {1400, 1600}, Axes -> False, 
      FrameLabel -> {"Rebate", "Profit", "", ""}]
sol  =  Solve[D[p[r, 1], r] == 0, r]

The results are similar to what we saw before, only the profit is reduced. There will be no benefit to the dealer of offering a rebate if the rebate causes an increase in sales of less than 6.67% for each $100 of rebate offered.

Rebate causing a reduction in profit

The rebate concept will cause a reduction in profit if the rebate is too large compared to the percentage increase in buyers. For our original case, we can find the value of this rebate by solving for when the profits do not change:

pm  =  1500;
rin  =  15/100;
rsf  =  100;
p[r_, n_]  =  
        n*(1 + rin* r/rsf) (pm - r);
Solve[ p[r, 1] == pm, r]

We see that if the rebate is $250/3/car, the profits do not change. So if the rebate is over $833.33 the dealer will lose money with the rebate plan. This is close to what we had guessed earlier.